Moving to Doom Emacs!

.emacs.d/modules/lang/java/+eclim.el

@@ -0,0 +1,50 @@
+;;; lang/java/+eclim.el -*- lexical-binding: t; -*-
+;;;###if (featurep! +eclim)
+
+;; NOTE This submodule is incomplete
+
+(use-package! eclim
+  :hook (java-mode . eclim-mode)
+  :config
+  (set-lookup-handlers! 'java-mode
+    :definition #'eclim-java-find-declaration
+    :references #'eclim-java-find-references
+    :documentation #'eclim-java-show-documentation-for-current-element)
+
+  (require 'eclimd)
+  (setq help-at-pt-display-when-idle t
+        help-at-pt-timer-delay 0.1)
+  (help-at-pt-set-timer)
+
+  (map! :localleader
+        :map java-mode-map
+        (:prefix ("r" . "refactor")
+          "gc" #'eclim-java-constructor
+          "gg" #'eclim-java-generate-getter-and-setter
+          "oi" #'eclim-java-import-organize
+          "f"  #'eclim-java-format
+          "r"  #'eclim-java-refactor-rename-symbol-at-point)
+        (:prefix ("h" . "help")
+          "."  #'eclim-java-show-documentation-for-current-element
+          "r"  #'eclim-java-find-references
+          "c"  #'eclim-java-call-hierarchy
+          "h"  #'eclim-java-hierarchy
+          "p"  #'eclim-problems
+          "r"  #'meghanada-reference
+          "t"  #'meghanada-typeinfo)
+        (:prefix ("b" . "build")
+          "b"  #'eclim-project-build
+          "c"  #'eclim-project-create
+          "d"  #'eclim-project-delete
+          "g"  #'eclim-project-goto
+          "i"  #'eclim-project-import
+          "k"  #'eclim-project-close
+          "o"  #'eclim-project-open
+          "u"  #'eclim-project-update)))
+
+
+(use-package! company-emacs-eclim
+  :when (featurep! :completion company)
+  :after java-mode
+  :config
+  (set-company-backend! 'java-mode '(company-emacs-eclim)))

.emacs.d/modules/lang/java/+lsp.el

@@ -0,0 +1,12 @@
+;;; lang/java/+lsp.el -*- lexical-binding: t; -*-
+;;;###if (featurep! +lsp)
+
+(use-package! lsp-java
+  :after-call java-mode
+  :init
+  (add-hook 'java-mode-local-vars-hook #'lsp!)
+  (setq lsp-java-server-install-dir (concat doom-etc-dir "eclipse.jdt.ls/server/"))
+  :config
+  ;; TODO keybinds
+  ;; TODO treemacs integration (?)
+  )

.emacs.d/modules/lang/java/+meghanada.el

@@ -0,0 +1,29 @@
+;;; lang/java/+meghanada.el -*- lexical-binding: t; -*-
+;;;###if (featurep! +meghanada)
+
+(use-package! meghanada
+  :hook (java-mode . meghanada-mode)
+  :init
+  (setq meghanada-server-install-dir (concat doom-etc-dir "meghanada-server/")
+        meghanada-use-company (featurep! :completion company)
+        meghanada-use-flycheck (featurep! :tools flycheck)
+        meghanada-use-eldoc t
+        meghanada-use-auto-start t)
+  :config
+  (set-lookup-handlers! 'java-mode
+    :definition #'meghanada-jump-declaration
+    :references #'meghanada-reference)
+
+  (map! :localleader
+        :map java-mode-map
+        (:prefix ("r" . "refactor")
+          "ia" #'meghanada-import-all
+          "io" #'meghanada-optimize-import
+          "l"  #'meghanada-local-variable
+          "f"  #'meghanada-code-beautify)
+        (:prefix ("h" . "help")
+          "r"  #'meghanada-reference
+          "t"  #'meghanada-typeinfo)
+        (:prefix ("b" . "build")
+          "f"  #'meghanada-compile-file
+          "p"  #'meghanada-compile-project)))

.emacs.d/modules/lang/java/autoload.el

@@ -0,0 +1,73 @@
+;;; lang/java/config.el -*- lexical-binding: t; -*-
+
+;; yasnippet defuns
+;;;###autoload
+(defun +java-android-mode-is-layout-file ()
+  (and android-mode
+       (eq major-mode 'nxml-mode)
+       (string-equal (file-name-base (directory-file-name default-directory)) "layout")))
+
+;;;###autoload
+(defun +java-android-mode-in-tags (&rest tags)
+  (cl-find (android-mode-tag-name) tags))
+
+;;;###autoload
+(defun +java-android-mode-tag-name ()
+  (save-excursion
+    (let (beg end)
+      (nxml-backward-up-element)
+      (evil-forward-word-begin)
+      (setq beg (point))
+      (evil-forward-WORD-end)
+      (setq end (1+ (point)))
+      (buffer-substring-no-properties beg end))))
+
+;;;###autoload
+(defun +java-android-mode-maybe-h ()
+  "Enable `android-mode' if this looks like an android project.
+
+It determines this by the existence of AndroidManifest.xml or
+src/main/AndroidManifest.xml."
+  (when (project-file-exists-p! (or "AndroidManifest.xml"
+                                    "src/main/AndroidManifest.xml"))
+    (android-mode +1)))
+
+;;;###autoload
+(defun +java-current-package ()
+  "Converts the current file's path into a namespace.
+
+For example: ~/some/project/src/net/lissner/game/MyClass.java
+Is converted to: net.lissner.game
+
+It does this by ignoring everything before the nearest package root (see
+`+java-project-package-roots' to control what this function considers a package
+root)."
+  (unless (eq major-mode 'java-mode)
+    (user-error "Not in a java-mode buffer"))
+  (let* ((project-root (file-truename (doom-project-root)))
+         (file-path (file-name-sans-extension
+                     (file-truename (or buffer-file-name
+                                        default-directory))))
+         (src-root (cl-loop for root in +java-project-package-roots
+                            if (and (stringp root)
+                                    (locate-dominating-file file-path root))
+                            return (file-name-directory (file-relative-name file-path (expand-file-name root it)))
+                            if (and (integerp root)
+                                    (> root 0)
+                                    (let* ((parts (split-string (file-relative-name file-path project-root) "/"))
+                                           (fixed-parts (reverse (nbutlast (reverse parts) root))))
+                                      (when fixed-parts
+                                        (string-join fixed-parts "/"))))
+                            return it)))
+    (when src-root
+      (string-remove-suffix "." (replace-regexp-in-string "/" "." src-root)))))
+
+;;;###autoload
+(defun +java-current-class ()
+  "Get the class name for the current file."
+  (unless (eq major-mode 'java-mode)
+    (user-error "Not in a java-mode buffer"))
+  (unless buffer-file-name
+    (user-error "This buffer has no filepath; cannot guess its class name"))
+  (or (file-name-sans-extension (file-name-base (buffer-file-name)))
+      "ClassName"))

.emacs.d/modules/lang/java/config.el

@@ -0,0 +1,48 @@
+;;; lang/java/config.el -*- lexical-binding: t; -*-
+
+(defvar +java-project-package-roots (list "java/" "test/" "main/" "src/" 1)
+  "A list of relative directories (strings) or depths (integer) used by
+`+java-current-package' to delimit the namespace from the current buffer's full
+file path. Each root is tried in sequence until one is found.
+
+If a directory is encountered in the file path, everything before it (including
+it) will be ignored when converting the path into a namespace.
+
+An integer depth is how many directories to pop off the start of the relative
+file path (relative to the project root). e.g.
+
+Say the absolute path is ~/some/project/src/java/net/lissner/game/MyClass.java
+The project root is ~/some/project
+If the depth is 1, the first directory in src/java/net/lissner/game/MyClass.java
+  is removed: java.net.lissner.game.
+If the depth is 2, the first two directories are removed: net.lissner.game.")
+
+(after! projectile
+  (pushnew! projectile-project-root-files "gradlew" "build.gradle"))
+
+
+;;
+;; java-mode
+
+(add-hook 'java-mode-hook #'rainbow-delimiters-mode)
+
+(cond ((featurep! +lsp)       (load! "+lsp"))
+      ((featurep! +meghanada) (load! "+meghanada")))
+
+
+;;
+;; Common packages
+
+(use-package! android-mode
+  :commands android-mode
+  :init
+  (add-hook! '(java-mode-hook groovy-mode-hook nxml-mode-hook)
+             #'+java-android-mode-maybe-h)
+  :config
+  (set-yas-minor-mode! 'android-mode))
+
+
+(use-package! groovy-mode
+  :mode "\\.g\\(?:radle\\|roovy\\)$"
+  :config
+  (set-eval-handler! 'groovy-mode "groovy"))

.emacs.d/modules/lang/java/doctor.el

@@ -0,0 +1,9 @@
+;; -*- lexical-binding: t; no-byte-compile: t; -*-
+;;; lang/java/doctor.el
+
+(assert! (or (not (featurep! +lsp))
+             (featurep! :tools lsp))
+         "This module requires (:tools lsp)")
+
+(unless (executable-find "javac")
+  (warn! "Couldn't find the javac executable, are you sure the JDK is installed?"))

.emacs.d/modules/lang/java/packages.el

@@ -0,0 +1,16 @@
+;; -*- no-byte-compile: t; -*-
+;;; lang/java/packages.el
+
+(package! android-mode)
+(package! groovy-mode)
+
+(when (featurep! +meghanada)
+  (package! meghanada))
+
+(when (featurep! +eclim)
+  (package! eclim)
+  (when (featurep! :completion company)
+    (package! company-emacs-eclim)))
+
+(when (featurep! +lsp)
+  (package! lsp-java))