Moving to Doom Emacs!

.emacs.d/modules/tools/lsp/README.org

@@ -0,0 +1,73 @@
+#+TITLE:   tools/lsp
+#+DATE:    March 05, 2019
+#+SINCE:   v2.1
+#+STARTUP: inlineimages
+
+* Table of Contents :TOC_3:noexport:
+- [[#description][Description]]
+  - [[#module-flags][Module Flags]]
+  - [[#plugins][Plugins]]
+- [[#prerequisites][Prerequisites]]
+- [[#features][Features]]
+- [[#configuration][Configuration]]
+- [[#troubleshooting][Troubleshooting]]
+
+* Description
+This module integrates [[https://langserver.org/][language servers]] into Doom Emacs. They provide features
+you'd expect from IDEs, like code completion, realtime linting, language-aware
+imenu/xref integration, jump-to-definition/references support, and more.
+
+To get LSP working, you'll need to do three things:
+
+1. Enable this module,
+2. Install a language server appropriate for your targeted language(s) (you'll
+   find a table mapping languages to available servers [[https://github.com/emacs-lsp/lsp-mode#supported-languages][in the lsp-mode project
+   README]]).
+3. Enable the =+lsp= flag on the =:lang= modules you want to enable LSP support
+   for. If your language's module doesn't have LSP support, and you know it can
+   (or should), please let us know! In the meantime, you must configure it
+   yourself (described in the Configuration section).
+
+As of this writing, this is the state of LSP support in Doom Emacs:
+
+| Module           | Major modes                                             | Default language server                                       |
+|------------------+---------------------------------------------------------+---------------------------------------------------------------|
+| [[../../lang/cc/README.org][:lang cc]]         | c-mode, c++-mode, objc-mode                             | ccls                                                          |
+| [[../../lang/csharp/README.org][:lang csharp]]     | csharp-mode                                             | omnisharp                                                     |
+| [[../../lang/elixir/README.org][:lang elixir]]     | elixir-mode                                             | elixir-ls                                                     |
+| [[../../lang/fsharp/README.org][:lang fsharp]]     | fsharp-mode                                             | Mono, .NET core                                               |
+| [[../../lang/go/README.org][:lang go]]         | go-mode                                                 | go-langserver                                                 |
+| [[../../lang/haskell/README.org][:lang haskell]]    | haskell-mode                                            | haskell-ide-engine                                            |
+| [[../../lang/java/README.org][:lang java]]       | java-mode                                               | lsp-java                                                      |
+| [[../../lang/javascript/README.org][:lang javascript]] | js2-mode, rjsx-mode, typescript-mode                    | typescript-language-server                                    |
+| [[../../lang/ocaml/README.org][:lang ocaml]]      | taureg-mode                                             | ocaml-language-server                                         |
+| [[../../lang/php/README.org][:lang php]]        | php-mode                                                | php-language-server                                           |
+| [[../../lang/python/README.org][:lang python]]     | python-mode                                             | lsp-python-ms                                                 |
+| [[../../lang/ruby/README.org][:lang ruby]]       | ruby-mode, enh-ruby-mode                                | solargraph                                                    |
+| [[../../lang/rust/README.org][:lang rust]]       | rust-mode                                               | rls                                                           |
+| [[../../lang/scala/README.org][:lang scala]]      | scala-mode                                              | metals                                                        |
+| [[../../lang/sh/README.org][:lang sh]]         | sh-mode                                                 | bash-language-server                                          |
+| [[../../lang/swift/README.org][:lang swift]]      | swift-mode                                              | sourcekit                                                     |
+| [[../../lang/web/README.org][:lang web]]        | web-mode, css-mode, scss-mode, sass-mode, less-css-mode | vscode-css-languageserver-bin, vscode-html-languageserver-bin |
+
+** Module Flags
+This module provides no flags.
+
+** Plugins
++ [[https://github.com/emacs-lsp/lsp-mode][lsp-mode]]
++ [[https://github.com/emacs-lsp/lsp-ui][lsp-ui]]
++ [[https://github.com/tigersoldier/company-lsp][company-lsp]]*
+
+* Prerequisites
+This module has no direct prerequisites, but major-modes require you to install
+language servers.
+
+You'll find a table that lists available language servers and how to install
+them [[https://github.com/emacs-lsp/lsp-mode#supported-languages][in the lsp-mode project README]]. The documentation of the module for your
+targeted language will contain brief instructions as well.
+
+* TODO Features
+
+* TODO Configuration
+
+* TODO Troubleshooting

.emacs.d/modules/tools/lsp/autoload.el

@@ -0,0 +1,4 @@
+;;; feature/lsp/autoload.el -*- lexical-binding: t; -*-
+
+;;;###autodef
+(defalias 'lsp! #'lsp-deferred)

.emacs.d/modules/tools/lsp/config.el

@@ -0,0 +1,150 @@
+;;; tools/lsp/config.el -*- lexical-binding: t; -*-
+
+(defvar +lsp-company-backend 'company-lsp
+  "What backend to prepend to `company-backends' when `lsp-mode' is active.
+
+This can be a single company backend or a list thereof. It can be anything
+`company-backends' will accept.")
+
+
+;;
+;;; Packages
+
+(use-package! lsp-mode
+  :defer t
+  :init
+  (setq lsp-session-file (concat doom-etc-dir "lsp-session"))
+  ;; Don't prompt the user for the project root every time we open a new
+  ;; lsp-worthy file, instead, try to guess it with projectile.
+  (setq lsp-auto-guess-root t)
+  ;; Auto-kill LSP server once you've killed the last buffer associated with its
+  ;; project.
+  (setq lsp-keep-workspace-alive nil)
+
+  ;; For `lsp-clients'
+  (setq lsp-fsharp-server-install-dir (concat doom-etc-dir "lsp-fsharp/")
+        lsp-groovy-server-install-dir (concat doom-etc-dir "lsp-groovy/")
+        lsp-intelephense-storage-path (concat doom-cache-dir "lsp-intelephense/"))
+
+  :config
+  (set-lookup-handlers! 'lsp-mode :async t
+    :documentation 'lsp-describe-thing-at-point
+    :definition 'lsp-find-definition
+    :references 'lsp-find-references)
+
+  (defvar +lsp--deferred-shutdown-timer nil)
+  (defadvice! +lsp-defer-server-shutdown-a (orig-fn)
+    "Defer server shutdown for a few seconds.
+This gives the user a chance to open other project files before the server is
+auto-killed (which is usually an expensive process)."
+    :around #'lsp--shutdown-workspace
+    (if (or lsp-keep-workspace-alive
+            (eq (lsp--workspace-shutdown-action lsp--cur-workspace)
+                'restart))
+        (funcall orig-fn)
+      (when (timerp +lsp--deferred-shutdown-timer)
+        (cancel-timer +lsp--deferred-shutdown-timer))
+      (setq +lsp--deferred-shutdown-timer
+            (run-at-time
+             3 nil (lambda (workspace)
+                     (let ((lsp--cur-workspace workspace))
+                       (unless (lsp--workspace-buffers lsp--cur-workspace)
+                         (funcall orig-fn))))
+             lsp--cur-workspace))))
+
+  (defadvice! +lsp-prompt-if-no-project-a (session file-name)
+    "Prompt for the project root only if no project was found."
+    :after-until #'lsp--calculate-root
+    (cond ((not lsp-auto-guess-root)
+           nil)
+          ((cl-find-if (lambda (dir)
+                         (and (lsp--files-same-host dir file-name)
+                              (file-in-directory-p file-name dir)))
+                       (lsp-session-folders-blacklist session))
+           nil)
+          ((lsp--find-root-interactively session))))
+
+  (defadvice! +lsp-init-a (&optional arg)
+    "Enable `lsp-mode' in the current buffer.
+
+Meant to be a lighter alternative to `lsp', which is too eager about
+initializing lsp-ui-mode, company, yasnippet and flycheck. Instead, these have
+been moved out to their respective modules, or these hooks:
+
++ `+lsp-init-company-h' (on `lsp-mode-hook')
++ `+lsp-init-ui-flycheck-or-flymake-h' (on `lsp-ui-mode-hook')
+
+Also logs the resolved project root, if found."
+    :override #'lsp
+    (interactive "P")
+    (require 'lsp-mode)
+    (when lsp-auto-configure
+      (require 'lsp-clients))
+    (and (buffer-file-name)
+         (setq-local
+          lsp--buffer-workspaces
+          (or (lsp--try-open-in-library-workspace)
+              (lsp--try-project-root-workspaces
+               (equal arg '(4))
+               (and arg (not (equal arg 1))))))
+         (prog1 (lsp-mode 1)
+           ;; Announce what project root we're using, for diagnostic purposes
+           (if-let (root (lsp--calculate-root (lsp-session) (buffer-file-name)))
+               (lsp--info "Guessed project root is %s" (abbreviate-file-name root))
+             (lsp--info "Could not guess project root."))
+           (lsp--info "Connected to %s."
+                      (apply #'concat
+                             (mapcar
+                              (lambda (it) (format "[%s]" (lsp--workspace-print it)))
+                              lsp--buffer-workspaces))))))
+
+  ;; Don't prompt to restart LSP servers while quitting Emacs
+  (add-hook! 'kill-emacs-hook (setq lsp-restart 'ignore)))
+
+
+(use-package! lsp-ui
+  :hook (lsp-mode . lsp-ui-mode)
+  :init
+  (add-hook! 'lsp-ui-mode-hook
+    (defun +lsp-init-ui-flycheck-or-flymake-h ()
+      "Sets up flymake-mode or flycheck-mode, depending on `lsp-prefer-flymake'."
+      (cond ((eq :none lsp-prefer-flymake))
+            (lsp-prefer-flymake
+             (lsp--flymake-setup))
+            ((require 'flycheck nil t)
+             (require 'lsp-ui-flycheck)
+             (lsp-ui-flycheck-enable t)))))
+  :config
+  (setq lsp-prefer-flymake nil
+        lsp-ui-doc-max-height 8
+        lsp-ui-doc-max-width 35
+        lsp-ui-sideline-ignore-duplicate t
+        ;; lsp-ui-doc is redundant with and more invasive than
+        ;; `+lookup/documentation'
+        lsp-ui-doc-enable nil
+        ;; Don't show symbol definitions in the sideline. They are pretty noisy,
+        ;; and there is a bug preventing Flycheck errors from being shown (the
+        ;; errors flash briefly and then disappear).
+        lsp-ui-sideline-show-hover nil)
+
+  (set-lookup-handlers! 'lsp-ui-mode :async t
+    :definition 'lsp-ui-peek-find-definitions
+    :references 'lsp-ui-peek-find-references))
+
+
+(use-package! company-lsp
+  :when (featurep! :completion company)
+  :defer t
+  :init
+  ;; Make sure that `company-capf' is disabled since it is incompatible with
+  ;; `company-lsp' (see lsp-mode#884)
+  (add-hook! 'lsp-mode-hook
+    (defun +lsp-init-company-h ()
+      (if (not (bound-and-true-p company-mode))
+          (add-hook 'company-mode-hook #'+lsp-init-company-h t t)
+        (setq-local company-backends
+                    (cons +lsp-company-backend
+                          (remq 'company-capf company-backends)))
+        (remove-hook 'company-mode-hook #'+lsp-init-company-h t))))
+  :config
+  (setq company-lsp-cache-candidates 'auto)) ;; cache candidates for better performance

.emacs.d/modules/tools/lsp/packages.el

@@ -0,0 +1,7 @@
+;; -*- no-byte-compile: t; -*-
+;;; tools/lsp/packages.el
+
+(package! lsp-mode)
+(package! lsp-ui)
+(when (featurep! :completion company)
+  (package! company-lsp))